Wikiversity

Datei:Hyperbolic orbit.gif

Hyperbolic_orbit.gif ‎(300 × 300 Pixel, Dateigröße: 12 KB, MIME-Typ: image/gif, Endlosschleife, 90 Bilder, 4,2 s)


Diese Datei und die Informationen unter dem roten Trennstrich werden aus dem zentralen Medienarchiv Commons eingebunden.
Weitere Informationen und eine Kontaktmöglichkeit zum Urheber sind dort zu finden. 		Zur Beschreibungsseite auf Commons Zur Beschreibungsseite auf Commons


 
Diese Grafik wurde mit POV-Ray erstellt.
a Semimajor axis
rp Periapsis' Radius
υ∞ Divergence angle

Beschreibung

Beschreibung Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue).
Datum
Quelle Own work. Rendered with PovRay-3.0, animated with gifsicle.
Urheber Brandir
Genehmigung
(Weiternutzung dieser Datei)		 Brandir put it under the GFCL and the CC-BY-SA

Lizenz

Ich, der Urheberrechtsinhaber dieses Werkes, veröffentliche es hiermit unter der folgenden Lizenz:
GNU head Es ist erlaubt, die Datei unter den Bedingungen der GNU-Lizenz für freie Dokumentation, Version 1.2 oder einer späteren Version, veröffentlicht von der Free Software Foundation, zu kopieren, zu verbreiten und/oder zu modifizieren; es gibt keine unveränderlichen Abschnitte, keinen vorderen und keinen hinteren Umschlagtext.

Der vollständige Text der Lizenz ist im Kapitel GNU-Lizenz für freie Dokumentation verfügbar.

w:de:Creative Commons
Namensnennung Weitergabe unter gleichen Bedingungen 		Diese Datei ist unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 3.0 nicht portiert“ lizenziert.
Dieses Werk darf von dir
  • verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
  • neu zusammengestellt werden – abgewandelt und bearbeitet werden
Zu den folgenden Bedingungen:
  • Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
  • Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.
Diese Lizenzmarkierung wurde auf Grund der GFDL-Lizenzaktualisierung hinzugefügt.
w:de:Creative Commons
Namensnennung Weitergabe unter gleichen Bedingungen
Diese Datei ist unter der Creative-Commons-Lizenz „Namensnennung – Weitergabe unter gleichen Bedingungen 2.5 Spanien“ lizenziert.
Dieses Werk darf von dir
  • verbreitet werden – vervielfältigt, verbreitet und öffentlich zugänglich gemacht werden
  • neu zusammengestellt werden – abgewandelt und bearbeitet werden
Zu den folgenden Bedingungen:
  • Namensnennung – Du musst angemessene Urheber- und Rechteangaben machen, einen Link zur Lizenz beifügen und angeben, ob Änderungen vorgenommen wurden. Diese Angaben dürfen in jeder angemessenen Art und Weise gemacht werden, allerdings nicht so, dass der Eindruck entsteht, der Lizenzgeber unterstütze gerade dich oder deine Nutzung besonders.
  • Weitergabe unter gleichen Bedingungen – Wenn du das Material wiedermischst, transformierst oder darauf aufbaust, musst du deine Beiträge unter der gleichen oder einer kompatiblen Lizenz wie das Original verbreiten.
Du darfst es unter einer der obigen Lizenzen deiner Wahl verwenden.

POV-Ray Scene description

POV-ray image description: 

 /*
 --------------------------
 Hyperbolic Orbit Animation
 --------------------------
 Created 7 Mar. 2006
 */
     
 #include "colors.inc"
 
 //Orbit Definition
 #declare OrbitA=30;
 #declare OrbitE=1.38;
 
 //Scene Constants
 #declare EarthRadius=6.356;
 #declare SatRadius=1.2;
 #declare OrbitWidth=0.5;
 #declare LineWidth=0.5/3;
 #declare Crosslength=1.5;
 #declare Textscale=9;
 #declare TextColor=rgb<0,0,0>;
 #declare xinit=-35;
 
 //Variables
 #declare Minit=OrbitE*sinh(acosh(-(xinit/OrbitA-OrbitE)))-acosh(-(xinit/OrbitA-OrbitE));
 #declare M=Minit-2*clock*Minit;
 #declare PI=3.14159265359;
 #declare Angleinf=180-acos(-1/OrbitE)*(180/PI);
 
 //Anomaly Determination - Solves the equation M=e*sinh(H)-H by the iterative method
 #declare Index=0;
 #declare prevAnomaly=0;
 #declare Anomaly=0;
 #while (Index<30)
     #declare Anomaly=asinh((M+prevAnomaly)/OrbitE);
     #declare prevAnomaly=Anomaly;
     #declare Index=Index+1;
 #end
 
 //General settings
 global_settings{
     ambient_light 1
     }
 
 light_source { <-50, 0, -70> color White }
 
 camera {
   orthographic
   location <-10, 0, -10>
   look_at  <-10, 0,  0>
   up <0,100,0>
   right <100,0,0>
 }
 
 
 plane { <0, 0, 1>, 8
     pigment {White}
     finish{ambient 1 brilliance 0}
 }
 
 
 //Earth
 sphere {
     <0, 0, 0>, EarthRadius
     pigment { Blue }
     finish{ ambient 0.3 brilliance 1.2 diffuse 0.8}
 }
 
 
 //Orbit
 intersection{
     box{
         <-100,-100,-OrbitWidth>, <100,100,OrbitWidth> 
     }
     quadric{
         <1/(OrbitA*OrbitA),-1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<2*OrbitE/OrbitA,0,0>,OrbitE*OrbitE-1
         translate x*OrbitWidth/2
     }
     quadric{
         <-1/(OrbitA*OrbitA),1/(OrbitA*OrbitA*(OrbitE*OrbitE-1)),0>,<0,0,0>,<-2*OrbitE/OrbitA,0,0>,1-OrbitE*OrbitE
         translate -x*OrbitWidth/2
     }
     pigment{ rgb<0.8,0,0> }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate 2.2*y
     no_shadow
 }
 
 
 //Satellite
 sphere {
     <0, 0, -10>, SatRadius
     pigment { SeaGreen }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
     translate <-OrbitA*(OrbitE-cosh(Anomaly)),OrbitA*sqrt(OrbitE*OrbitE-1)*sinh(Anomaly),0>
 }
 
 //Lines
 #declare crossBars=
 object{
     union{
         box{
             <-LineWidth,-Crosslength,-LineWidth-7>, <LineWidth,Crosslength,LineWidth-7> 
         }
         box{
             <-Crosslength,-LineWidth,-LineWidth-7>, <Crosslength,LineWidth,LineWidth-7>
         }
         rotate z*45
         pigment{ TextColor }
         finish{ ambient 1 brilliance 0 diffuse 0}
         no_shadow
     }
 }
 
 box{
     <-OrbitA*OrbitE-3,-LineWidth,-LineWidth-7>, <0,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 box{
     <0,-LineWidth,-LineWidth-7>, <300,LineWidth,LineWidth-7> 
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     rotate -z*Angleinf
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 difference{
     torus{
         4,LineWidth
         rotate x*90
     }
     box {
         <-5,0,-5>,<5,5,5>
     }
     box {
         <-5,-5,-5>,<5,0,5>
         rotate -z*Angleinf
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     translate -z*7
     translate -x*OrbitA*OrbitE
     no_shadow
 }
 
 object{
     crossBars
 }
 
 object{
     crossBars
     translate -x*OrbitA*(OrbitE-1)
 }
 
 object{
     crossBars
     translate -x*OrbitA*OrbitE
 }
 
 //Text
 text {
     ttf "timesi.ttf" "a" 1, 0
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <OrbitA*(0.5-OrbitE)-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "timesi.ttf" "r" 1, 0
     }
     text {
         ttf "timesi.ttf" "p" 1, 0
         scale 0.5
         translate 0.2*x
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-(EarthRadius+0.3*(OrbitA*(OrbitE-1)-EarthRadius))-Textscale/4,Textscale/4,-7>
     no_shadow
 }
 
 union{
     text {
         ttf "symbol.ttf" "u" 1, 0
         matrix 
             < 1, 0, 0,
             0.3, 1, 0,
             0, 0, 1,
             0, 0, 0 >
     }
     text {
         ttf "symbol.ttf" chr(165) 1, 0
         scale 0.5
         translate <0.6,-0.1,0>
     }
     pigment{ TextColor }
     finish{ ambient 1 brilliance 0 diffuse 0}
     scale Textscale
     translate <-OrbitA*OrbitE-Textscale/4+9,-0.6*Textscale,-7>
     no_shadow
 }

Kurzbeschreibungen

Ergänze eine einzeilige Erklärung, was diese Datei darstellt.

In dieser Datei abgebildete Objekte

Motiv

MIME-Typ

image/gif

Dateiversionen

Klicke auf einen Zeitpunkt, um diese Version zu laden.

Version vomVorschaubildMaßeBenutzerKommentar
aktuell02:01, 8. Mär. 2006Vorschaubild der Version vom 02:01, 8. Mär. 2006300 × 300 (12 KB)Brandir~commonswiki{{Information| |Description = Animation showing the motion of a small body (green) in an hyperbolic orbit around a much more massive body (blue). |Source = Own work. Rendered with ''PovRay-3.0'', animated with ''gifsicle''. |Date = Created 7. Mar. 2006.

Globale Dateiverwendung

Die nachfolgenden anderen Wikis verwenden diese Datei:

Abgerufen von „https://de.wikiversity.org/wiki/Datei:Hyperbolic_orbit.gif“